plugins {
    id 'com.diffplug.spotless' version '6.22.0'
    id 'java-library'
    id 'maven-publish'
    id 'org.danilopianini.git-sensitive-semantic-versioning' version '7.0.24'
}

group = 'com.majinnaibu.minecraft.plugins'
description = "ScoreKeeper"

gitSemVer {
    minimumVersion.set('0.2.1')
    versionPrefix.set('v')
}

tasks.withType(JavaCompile).configureEach {
	options.encoding = 'UTF-8'
    // options.compilerArgs << "-Xlint:deprecation"
}

tasks.withType(Javadoc).configureEach {
	options.encoding = 'UTF-8'
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:26.2.build.129-stable'
}

java {
    toolchain {
        // Paper 26.1+ requires Java 25.
        languageVersion = JavaLanguageVersion.of(25)
    }
}

tasks.named('wrapper') {
    gradleVersion = '9.8.0'
    distributionType = Wrapper.DistributionType.BIN
    distributionBase = Wrapper.PathBase.PROJECT
    distributionPath = '.gradle/wrapper/dists'
    archiveBase = Wrapper.PathBase.PROJECT
    archivePath = '.gradle/wrapper/dists'
}

tasks.named('updateDaemonJvm') {
    languageVersion = JavaLanguageVersion.of(25)
}

def pluginVersion = project.version.toString()

processResources {
    inputs.property "version", pluginVersion
    filesMatching('plugin.yml') {
        expand(version: pluginVersion)
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
        }
    }
}

repositories {        
     mavenCentral()
     maven { url = 'https://repo.papermc.io/repository/maven-public/' }
}

spotless {
    java {
        googleJavaFormat('1.27.0')
        importOrder 'java', 'javax', 'com', 'net', 'org', ''
        licenseHeaderFile 'config/license-header.txt'
        target 'src/**/*.java'
        removeUnusedImports()
        toggleOffOn()
   }
}